testsuite/array_new_elem.wast at main · WebAssembly/testsuite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
;;;; Expression-style element segments.

(module
  (type $arr (array i31ref))

  (elem $e i31ref
    (ref.i31 (i32.const 0xaa))
    (ref.i31 (i32.const 0xbb))
    (ref.i31 (i32.const 0xcc))
    (ref.i31 (i32.const 0xdd)))

  (func (export "array-new-elem") (param i32 i32) (result (ref $arr))
    (array.new_elem $arr $e (local.get 0) (local.get 1))
  )
)

;; In-bounds element segment accesses.
(assert_return (invoke "array-new-elem" (i32.const 0) (i32.const 0)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 0) (i32.const 4)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 1) (i32.const 2)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 4) (i32.const 0)) (ref.array))

;; Out-of-bounds element segment accesses.
(assert_trap (invoke "array-new-elem" (i32.const 0) (i32.const 5)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 5) (i32.const 0)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 1) (i32.const 4)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 4) (i32.const 1)) "out of bounds table access")

(module
  (type $arr (array i31ref))

  (elem $e i31ref
    (ref.i31 (i32.const 0xaa))
    (ref.i31 (i32.const 0xbb))
    (ref.i31 (i32.const 0xcc))
    (ref.i31 (i32.const 0xdd)))

  (func (export "array-new-elem-contents") (result i32 i32)
    (local (ref $arr))
    (local.set 0 (array.new_elem $arr $e (i32.const 1) (i32.const 2)))
    (i31.get_u (array.get $arr (local.get 0) (i32.const 0)))
    (i31.get_u (array.get $arr (local.get 0) (i32.const 1)))
  )
)

;; Array is initialized with the correct contents.
(assert_return (invoke "array-new-elem-contents") (i32.const 0xbb) (i32.const 0xcc))

;;;; MVP-style function-index segments.

(module
  (type $arr (array funcref))

  (elem $e func $aa $bb $cc $dd)
  (func $aa (result i32) (i32.const 0xaa))
  (func $bb (result i32) (i32.const 0xbb))
  (func $cc (result i32) (i32.const 0xcc))
  (func $dd (result i32) (i32.const 0xdd))

  (func (export "array-new-elem") (param i32 i32) (result (ref $arr))
    (array.new_elem $arr $e (local.get 0) (local.get 1))
  )
)

;; In-bounds element segment accesses.
(assert_return (invoke "array-new-elem" (i32.const 0) (i32.const 0)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 0) (i32.const 4)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 1) (i32.const 2)) (ref.array))
(assert_return (invoke "array-new-elem" (i32.const 4) (i32.const 0)) (ref.array))

;; Out-of-bounds element segment accesses.
(assert_trap (invoke "array-new-elem" (i32.const 0) (i32.const 5)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 5) (i32.const 0)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 1) (i32.const 4)) "out of bounds table access")
(assert_trap (invoke "array-new-elem" (i32.const 4) (i32.const 1)) "out of bounds table access")

(module
  (type $f (func (result i32)))
  (type $arr (array funcref))

  (elem $e func $aa $bb $cc $dd)
  (func $aa (result i32) (i32.const 0xaa))
  (func $bb (result i32) (i32.const 0xbb))
  (func $cc (result i32) (i32.const 0xcc))
  (func $dd (result i32) (i32.const 0xdd))

  (table $t 2 2 funcref)

  (func (export "array-new-elem-contents") (result i32 i32)
    (local (ref $arr))
    (local.set 0 (array.new_elem $arr $e (i32.const 1) (i32.const 2)))

    (table.set $t (i32.const 0) (array.get $arr (local.get 0) (i32.const 0)))
    (table.set $t (i32.const 1) (array.get $arr (local.get 0) (i32.const 1)))

    (call_indirect (type $f) (i32.const 0))
    (call_indirect (type $f) (i32.const 1))

  )
)

;; Array is initialized with the correct contents.
(assert_return (invoke "array-new-elem-contents") (i32.const 0xbb) (i32.const 0xcc))

;; Test that element segments are not re-evaluated on every `array.new_elem`.
(module
  (type $arr (array (mut arrayref)))
  (elem $elem arrayref (item (array.new_default $arr (i32.const 0))))
  (func (export "run") (result i32)
    (local $a (ref null $arr))
    (local $b (ref null $arr))

    (local.set $a (array.new_elem $arr $elem (i32.const 0) (i32.const 1)))
    (local.set $b (array.new_elem $arr $elem (i32.const 0) (i32.const 1)))

    (ref.eq (array.get $arr (local.get $a) (i32.const 0))
            (array.get $arr (local.get $b) (i32.const 0)))
  )
)

(assert_return (invoke "run") (i32.const 1))